L'objet ADO Property représente une caracéristique dynamique d'un objet ADO qui est défini par un fournisseur.
Un objet ADO possède deux types de propriétés, en l'occurrence programmé et dynamique.
Les premières sont celles exécutées dans ADO et sont immédiatement disponible à partir de n'importe quel objet nouvellement créé, en utilisant la syntaxe ci-dessous.
Objet.Property
Les propriétés programmées n'apparaissent pas comme des objets Property dans un collection Properties. Bien qu'il soit possible de modifier leur valeur, en revanche la modification de leurs caractéristiques est impossible.
Objet.Property = Valeur
Les secondes sont définies par le fournisseur de données sous-jacent, et apparaissent dans la collection ¨Properties pour l'objet ADO approprié. Les propriétés additionnelles se présentent comme des objets Property de la collection Properties de l'objet Recordset.
Les propriétés dynamiques sont disponibles à partir de l'une ou l'autre des expressions suivantes :
Objet.Properties(Index)
Objet.Properties("Nom")| Propriété |
|---|
| Description |
| Objet_Property.Attributes = Entier |
| retourne un entier long indiquant les caractéristiques de la propriété spécifique au fournisseur. |
| Objet_Property.Name = Nom |
| retourne une chaîne de caractères qui identifie la propriété. |
| Objet_Property.Type = DataTypeEnum |
| retourne un entier indiquant le type de données de la propriété. |
| Objet_Property.Value = Valeur |
| retourne un variant correspondant à la valeur de la propriété. |
<html>
<body>
<%
Dim obj_Connection
Dim obj_Recordset
Dim ch_Source
Dim ch_SQL
set obj_Connection=server.CreateObject("ADODB.connection")
ch_Source = "Provider=Microsoft.Jet.OLEDB.4.0"
ch_Source = ch_Source & "; Data Source=C:\Base_donnee\Personnel.mdb"
obj_Connection.connectionstring = ch_Source
obj_Connection.Open
set obj_Recordset = server.CreateObject("ADODB.recordset")
ch_SQL = "SELECT Nom, Prenom FROM Fiche;"
obj_Recordset.Open ch_SQL,obj_Connection
Response.Write "<h3>Personnels :</h3>"
Do until obj_Recordset.EOF
Response.Write "<b>" & obj_Recordset("Nom") & "</b> " _
& obj_Recordset("Prenom") & "<br>"
obj_Recordset.MoveNext
Loop
Response.Write "<h3>Propriétés de l'objet Connection :</h3>" _
& "<table border=1>" _
& "<tr><th>N°</th>" _
& "<th>Type</th>" _
& "<th>Attribut</th>" _
& "<th>Nom</th>" _
& "<th>Valeur</th></tr>"
dim i
i = 0
for each obj_Property in obj_Connection.Properties
i = i + 1
Response.Write "<tr><td>" & i & "</td>"
Response.Write "<td>" & obj_Property.type & "</td>"
Response.Write "<td>" & obj_Property.attributes & "</td>"
Response.Write "<td>" & obj_Property.name & "</td>"
Response.Write "<td>" & obj_Property.value & "</td></tr>"
Next
Response.Write "</table>"
%>
</body>
</html> |