Le composant NextLink permet de gérer une liste d'adresses URL (Uniform Resource Locator) dans un fichier texte.

La déclaration ci-dessous, permet de créer une instance du composant NextLink sous VBScript.

Set objet = Server.CreateObject("MSWC.NextLink")

Sous JScript, il suffit de remplacer l'instruction Set par var si l'objet n'a pas été préalablement déclaré, sinon supprimer la simplement.

Le composant NextLink dépend du fichier librairie NextLink.dll et d'un fichier textuel spécifique contenant une liste d'adresses URL.

Le fichier texte contenant la liste d'adresses URL doit obéir à la construction suivante :

Adresse.url->Description->Commentaire
...
AdresseN.url->DescriptionN->CommentaireN

Une tabulation doit obligatoirement apparaître entre chaque élément et chaque URL doit commencer une nouvelle ligne.

Seules des adresses virtuelles relatives (rep/page.asp) ou physiques (rep\page.asp) sont acceptées par le composant NextLink.

Les adresses absolues (http://www.adresse.com) ne peuvent être utilisées telles quelles dans le fichier précité. Néanmoins, l'instruction Redirect peut permettre de s'affranchir de cette limitation.

redirection.asp?url=http://adresse.com
                 ->Description->Commentaire

Le fichier de redirection redirection.asp permet de récupérer l'adresse absolue et de la rediriger par l'intermédiaire de l'instruction Redirect.

<%
  Response.Clear
  Response.Redirect Request.QueryString("url")
%>
Les Méthodes
Méthode
Description
GetListCount(fichier_texte)
retourne le nombre de liens contenus dans le fichier texte.
GetListIndex(fichier_texte)
retourne l'index du lien de la page en cours du fichier texte.
GetNextDescription(fichier_texte)
retourne la description de la prochaîne page listée dans le fichier texte.
GetNextURL(fichier_texte)
retourne l'adresse URL de la prochaîne page listée dans le fichier texte.
GetNthDescription(fichier_texte, n-ieme_page)
retourne la description de la n-ième page dans le fichier texte.
GetNthURL(fichier_texte, n-ieme_page)
retourne l'adresse URL de la n-ième page listée dans le fichier texte.
GetPreviousDescription(fichier_texte)
retourne la description précédente des pages listées dans le fichier texte.
GetPreviousURL(fichier_texte)
retourne l'adresse URL précédente des pages listées dans le fichier texte.
Exemple [voir] 
<!-- Fichier nextlink.asp -->
<%@LANGUAGE="VBScript"%>
<html>
  <body>
    <%
      Set objLiens = Server.CreateObject("MSWC.Nextlink")
    %>
    <h2>Sommaire</h2>
    <h3>
      <a href="<% = objLiens.GetNthURL("liste_liens.txt", 1) %>">
        <% = objLiens.GetNthDescription("liste_liens.txt", i) %>
      </a>
    </h3>
    <ol>
    <%
      nbLiens = objLiens.GetListCount("liste_liens.txt")
      For i = 2 To nbLiens
    %>
      <li>
        <a href="<% = objLiens.GetNthURL("liste_liens.txt", i) %>">
          <% = objLiens.GetNthDescription("liste_liens.txt", i) %>
        </a>
      </li>
    <%
      Next
    %>
    </ol>
  </body>
</html>
<!-- Fichier liste_liens.txt -->
composant.html Les composants
objet_adrotator.html AdRotator
objet_browsertype.html BrowserType
objet_contentrotator.html ContentRotator
objet_counters.html Counters
objet_iislog.html IISLog
objet_myinfo.html MyInfo
objet_nexlink.html NextLink
objet_permissionchecker.html PermissionChecker
objet_tools.html Tools