L'objet IXMLDOMCharacterData fournit des méthodes permettant de manipuler du texte qui sont utilisées par plusieurs objets.
L'objet IXMLDOMCharacterData ne correspond directement à aucun type de noeud. Les méthodes sont réutilisées par les objets IXMLDOMCDATASection, IXMLDOMComment et IXMLDOMText.
Ces méthodes manipulent de grandes quantités de texte, y compris de très grandes tailles qui peuvent être manipulées nativement en utilisant les formes de chaînes de caractères.
Les Propriétés| Propriété |
|---|
| Description |
| Chaîne = Objet_CharacterDATA.baseName |
| retourne le nom de base pour le nom qualifié avec l'espace de noms en lecture seule. |
| Set Objet_NodeList = Objet_CharacterDATA.childNodes |
| contient une liste de noeuds contenant les enfants en lecture seule. |
| Chaîne = Objet_CharacterDATA.data |
| contient les données du noeud CDATA, en lecture et écriture. |
| Valeur = Objet_CharacterDATA.dataType |
| indique le type de données pour ce noeud en lecture et écriture. |
| Set Objet_Node = Objet_CharacterDATA.definition |
| retourne la définition d'un noeud dans le DTD ou le schéma en lecture seule. |
| Set Objet_Node = Objet_CharacterDATA.firstChild |
| contient le premier enfant de ce noeud en lecture seule. |
| Set Objet_Node = Objet_CharacterDATA.lastChild |
| retourne le dernier noeud enfant en lecture seule. |
| Valeur = Objet_CharacterDATA.length |
| spécifie la longueur, en caractères des données, en lecture seule. |
| Chaîne = Objet_CharacterDATA.namespaceURI |
| retourne l'URI (Uniform Resource Identifier) pour l'espace de noms en lecture seule. |
| Set Objet_Node = Objet_CharacterDATA.nextSibling |
| contient le frère suivant de ce noeud dans la liste d'enfants des parents en lecture seule. |
| Chaîne = Objet_CharacterDATA.nodeName |
| contient le nom qualifié de l'élément, l'attribut, la référence d'entité ou une chaîne de caractères fixée pour d'autres types de noeud en lecture seule. |
| Valeur = Objet_CharacterDATA.nodeType |
| spécifie le type de noeud XML DOM qui détermine des valeurs valides et si le noeud peut avoir des noeuds enfants en lecture seule. |
| Valeur = Objet_CharacterDATA.nodeTypedValue |
| contient la valeur de ce noeud exprimée dans son type de donnée défini en lecture et écriture. |
| Chaîne = Objet_CharacterDATA.nodeTypeString |
| retourne le type de noeud dans une forme de chaîne de caractères en lecture seule. |
| Valeur = Objet_CharacterDATA.nodeValue |
| contient le texte associé avec le noeud en lecture et écriture. |
| Set Objet_Document = Objet_CharacterDATA.ownerDocument |
| retourne la racine du document qui contient ce noeud en lecture seule. |
| Set Objet_Node = Objet_CharacterDATA.parentNode |
| contient le noeud parent en lecture seule. |
| True | False = Objet_CharacterDATA.parsed |
| contient la valeur True si le noeud et tous ses descendants ont été analysées et instanciées, ou False si n'importe quels noeuds restent à être analysées en lecture seule. |
| Valeur = Objet_CharacterDATA.prefix |
| retourne le préfixe d'espace de noms en lecture seule. |
| Set Objet_Node = Objet_CharacterDATA.previousSibling |
| contient le frère gauche de ce noeud en lecture seule. |
| True | False = Objet_CharacterDATA.specified |
| indique si le noeud est explicitement spécifié ou dérivé d'une valeur par défaut dans le DTD ou le schéma en lecture seule. |
| Chaîne = Objet_CharacterDATA.text |
| contient le contenu textuel du noeud et de sa sous-arborescence en lecture et écriture. |
| Valeur = Objet_CharacterDATA.xml |
| contient la représentation XML du noeud et de tous ses descendants en lecture seule. |
| Méthode |
|---|
| Description |
| Set Objet_CharacterDATA.appendChild(Nouvel_Enfant) |
| ajoute un nouvel enfant comme le dernier enfant de ce noeud. |
| Objet_CharacterDATA.appendData(Chaîne) |
| ajoute la chaîne de caractères spécifiée aux données textuelles existantes. |
| Set Objet_CharacterDATA.cloneNode(Bool_Profondeur) |
| crée un nouveau noeud qui est un double exact de ce noeud. |
| Objet_CharacterDATA.deleteData(Position, Nb_Caractères) |
| supprime la sous-chaîne de caractères à l'intérieur de données textuelles. |
| True | False = Objet_CharacterDATA.hasChildNodes() |
| retourne True si le noeud a des enfants. |
| Set Objet_CharacterDATA.insertBefore(Nouvel_Enfant, Référence) |
| insère un noeud enfant à la gauche du noeud spécifié ou à la fin de la liste. |
| Objet_CharacterDATA.insertData(Position) |
| insère la chaîne spécifiée à la position indiquée. |
| Set Objet_CharacterDATA.removeChild(Noeud_Enfant) |
| enlève le noeud enfant spécifié de la liste d'enfant et le retourne. |
| Set Objet_CharacterDATA.replaceChild(Nouvel_Enfant, Ancien_Enfant) |
| remplace l'ancien noeud enfant spécifié par le nouveau noeud enfant fourni dans le jeu d'enfants de ce noeud. |
| Objet_CharacterDATA.replaceData(Position, Nb_Caractères, Données) |
| remplace le nombre de caractères spécifiés par la chaîne de caractères fournie. |
| Set Objet_NodeList = Objet_CharacterDATA.selectNodes(Expression_Pattern) |
| applique l'opération de mise en correspondance de modèles indiquée au contexte de ce noeud et retourne la liste de noeuds correspondants. |
| Set Objet_CharacterDATA.selectSingleNode(Chaîne_Requête) |
| applique l'opération de mise en correspondance de modèles indiquée au contexte de ce noeud et retourne la liste de premier noeud correspondant. |
| True | False = Objet_CharacterDATA.specified |
| indique si le noeud est explicitement spécifié ou dérivé d'une valeur par défaut dans le DTD ou le schéma en lecture seule. |
| Chaîne = Objet_CharacterDATA.substringData(Position, Nb_Caractères) |
| récupère une sous-chaîne de caractères d'une chaîne complète à l'intervalle spécifié. |
| Chaîne = Objet_CharacterDATA.transformNode(Objet_StyleSheet) |
| traite ce noeud et ses enfants utilisant la feuille de style de tranformation (XSLT) indiquée et retourne la transformation résultante. |
| Objet_CharacterDATA.transformNodeToObject(Feuille_Style, Objet) |
| traite ce noeud et ses enfants utilisant la feuille de style de tranformation (XSLT) indiquée et retourne la transformation résultante dans l'objet fourni. |
<%
Dim Objet_Document, Objet_Style
Dim racine, PI_xml, PI_stylesheet, fichier_XSL
Dim Objet_CharacterData, oCommentaire
Dim oAuteur, cAuteur, oDecription, cDescription
Dim oNom, oOeuvres, oPoeme
Dim auteur, description, titre
Dim quatrain_A, quatrain_B, quatrain_C
Dim quatrain_D, quatrain_E, saut
Set Objet_Document = Server.CreateObject("MSXML2.DOMDocument")
Set Objet_Style = Server.CreateObject("MSXML2.DOMDocument")
fichier_XSL = Server.MapPath("recueil.xsl")
Objet_Style.async = False
Objet_Style.Load fichier_XSL
Set racine = Objet_Document.createElement("recueil")
Objet_Document.appendChild racine
saut = vbCrLf & vbCrLf
auteur = "Heinrich HEINE"
description = "Heinrich HEINE vécut en Allemagne entre 1797 et 1856." _
& "Il est un poète romantique par excellence, qui chante " _
& "l'amour entre la cruelle déception et un certain cynisme. " _
& "De plus, il a fortement influencé les milieux littéraires " _
& "parisiens, qu'il ne cessa de fréquenter jusqu'à sa mort."
titre = "Die Zeit"
quatrain_A = "Ah! qu'il est lent, ah comme il traîne," & vbCrLf _
& "le Temps horrible limaçon !" & vbCrLf _
& "Sans pouvoir remuer un membre," & vbCrLf _
& "je gis ici, cloué sur place."
quatrain_B = "En ma cellule ne vient luire" & vbCrLf _
& "nul rai de soleil ni d'espoir." & vbCrLf _
& "Jusqu'à la fosse au cimetière," & vbCrLf _
& "je suis voué à mon grabat."
quatrain_C = "Mourir, c'est déjà fait, peut-être;" & vbCrLf _
& "peut-être n'est-ce que fantômes," & vbCrLf _
& "ces visions qui font la foire" & vbCrLf _
& "toute la nuit dans mon cerveau."
quatrain_D = "Oui c'est peut-être le spectrale" & vbCrLf _
& "sarabande des dieux païens;" & vbCrLf _
& "pour leur ébats ça leur va bien," & vbCrLf _
& "le crâne creux d'un trépassé."
quatrain_E = "Mais la folle, la douce orgie," & vbCrLf _
& "ces bacchanales de la nuit," & vbCrLf _
& "la main du squelette se crispe" & vbCrLf _
& "au matin pour les esquisser."
Set Objet_CharacterDATA = Objet_Document.createTextNode(quatrain_B)
Set oAuteur = Objet_Document.createElement("auteur")
Set oNom = Objet_Document.createElement("nom")
Set cAuteur = Objet_Document.createTextNode(auteur)
Set oDescription = Objet_Document.createElement("description")
Set cDescription = Objet_Document.createTextNode(description)
Set oOeuvres = Objet_Document.createElement("oeuvres")
Set oPoeme = Objet_Document.createElement("poeme")
oPoeme.setAttribute "titre", titre
Objet_CharacterDATA.insertData 0, quatrain_A & saut
Objet_CharacterDATA.insertData _
Objet_CharacterDATA.length, saut
Objet_CharacterDATA.insertData _
Objet_CharacterDATA.length, quatrain_C & saut
Objet_CharacterDATA.insertData _
Objet_CharacterDATA.length, quatrain_D & saut
Objet_CharacterDATA.insertData _
Objet_CharacterDATA.length, quatrain_E
oAuteur.appendChild oNom
oDescription.appendChild cDescription
oAuteur.appendChild oDescription
oPoeme.appendChild Objet_CharacterDATA
oOeuvres.appendChild oPoeme
oAuteur.appendChild oOeuvres
oNom.appendChild cAuteur
oPoeme.normalize
racine.appendChild oAuteur
Set PI_xml = _
Objet_Document.createProcessingInstruction("xml", _
"version='1.0' encoding='iso-8859-1'")
Set PI_stylesheet = _
Objet_Document.createProcessingInstruction("xml-stylesheet", _
"type='text/xsl' href='" & fichier_XSL & "'")
Objet_Document.insertBefore PI_xml, racine
Objet_Document.insertBefore PI_stylesheet, racine
Set oCommentaire = _
Objet_Document.createComment("Fichier créé le " & date & ".")
racine.appendChild oCommentaire
Objet_Document.save Server.MapPath("recueil.xml")
Response.Write Objet_Document.transformNode(Objet_Style) _
& "<h4>Le fichier XML est disponible à l'adresse " _
& " suivante : " & Server.MapPath("recueil.xml") & "</h4>"
Set Objet_Document = Nothing
Set Objet_Style = Nothing
%> |