L'Altruiste : Le langage XSL - L'élément <xsl:if>

L'élément <xsl:if> permet d'appliquer un test conditionnel dans la structure d'une feuille de style XSL.

<xsl:if test="condition">
   Instructions...
</xsl:if>

Si le test conditionnel est vérifié alors le processeur XSL exécutera les instructions contenues à l'intérieur des marqueurs, sinon il les ignorera et passera aux instructions suivantes.

Les attributs :

Attribut	Description
test="condition"	permet de poser une condtion d'éxécution.

Cet élément peut être contenu dans les instructions suivantes :

Cet élément peut contenir les instructions suivantes :

Exemple : [voir]

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:transform version="1.0"
                       xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html" 
               media-type="text/html; charset=ISO-8859-1"/>
  <xsl:template match="/">
  <html>
      <head>
        <title>La logithèque</title>
      </head>
      <body>
        <table border="1">
        <tr>
          <th>N°</th>
          <th>Logiciel</th>
          <th>Langue</th>
        </tr>
        <xsl:apply-templates select="logitheque/categorie/logiciel"/>
        </table>
      </body>
  </html>
  </xsl:template>
  <xsl:template match="logitheque/categorie/logiciel">
  <tr>
      <td>
        <xsl:variable name="num">
        <xsl:number level="any" from="logitheque"/>
        </xsl:variable>
        <xsl:value-of select="$num"/>
      </td>
      <td>
        <a href="{editeur/@lien}" target="_blank"
            style="font-size:10pt; font-weight:bold">
        <xsl:apply-templates select="nom"/>
        </a>
          - <xsl:apply-templates select="commentaire"/>
      </td>
      <td>
        <xsl:if test="langue != 'FR'">
        <img src="../images/interface/drapeau_us.gif"
                  alt="Drapeau américain !"/>
        </xsl:if>
        <xsl:if test="langue != 'EN'">
        <img src="../images/interface/drapeau_fr.gif"
                  alt="Drapeau français !"/>
        </xsl:if>
      </td>
  </tr>
  </xsl:template>
</xsl:transform>

En savoir plus :