L'objet IXMLDOMDocumentFragment est un objet Document allégé qui est utilisable pour des opérations d'insertion.
Un fragment de document est créé par l'intermédiaire de la méthode createDocumentFragment de l'objet DOMDocument.
Set objet_DocumentFragment = _
objet_DOMDocument.createDocumentFragment()L'objet DocumentFragment peut représenter un fragment d'un document ou une portion de l'arborescence d'un document.
Les noeuds DocumentFragment ne doivent pas être des documents obéissant parfaitement aux règles grammaticales de XML, c'est-à-dire qu'ils n'ont pas besoin d'être bien formés. Par exemple, ce noeud peut avoir un seule enfant et que ce dernier peut être un noeud textuel ou bien il peut être composé de zéro à plusieurs noeuds représentant le niveau supérieur de n'importe quelles sous-arborescences définissant la structure du document. En clair, le noeud DocumentFragment peut possèder plusieurs noeuds racines.
<racine>
<comment>
La portion de l'arborescence en gras
représente un fragment de document.
</comment>
<enfant>
<petit_enfant>
...
</petit_enfant>
</enfant>
<enfant>
<petit_enfant>
...
</petit_enfant>
</enfant>
...
</racine>L'objet IXMLDOMDocumentFragment a été spécialement conçu pour effectuer des opérations d'insertion ou d'extraction à partir de l'arborescence d'un document XML.
La méthode appendChild permet d'ajouter un ou plusieurs noeuds dans un fragment de document ou d'ajouter l'objet IXMLDOMDocumentFragment à un noeud élément.
objet_DocumentFragment.appendChild objet_Liste_Noeuds Objet_Element.appendChild objet_DocumentFragment
L'objet DocumentFragment s'avère très utile lorsque l'utilisateur veut créer des noeuds frères, ainsi, l'objet se comporte comme le parent de ces noeuds afin que l'utilisateur puisse utiliser les méthodes standards de l'objet IXMLNode telles que insertBefore et appendChild.
Set objet_Node = _ DocumentFragment.insertBefore(Nouvel_Enfant, Noeud_Frère) |
| Propriété |
|---|
| Description |
| Set Objet_NamedNodeMap = Objet_DocumentFragment.attributes |
| contient la liste des attributs pour ce noeud en lecture seule. |
| Chaîne = Objet_DocumentFragment.baseName |
| retourne le nom de base pour le nom qualifié avec l'espace de noms en lecture seule. |
| Set Objet_NodeList = Objet_DocumentFragment.childNodes |
| contient une liste de noeuds contenant les enfants en lecture seule. |
| Valeur = Objet_DocumentFragment.dataType |
| indique le type de données pour ce noeud en lecture et écriture. |
| Set Objet_Node = Objet_DocumentFragment.definition |
| retourne la définition d'un noeud dans le DTD ou le schéma en lecture seule. |
| Set Objet_Node = Objet_DocumentFragment.firstChild |
| contient le premier enfant de ce noeud en lecture seule. |
| Set Objet_Node = Objet_DocumentFragment.lastChild |
| contient le dernier noeud enfant en lecture seule. |
| Chaîne = Objet_DocumentFragment.namespaceURI |
| retourne l'URI (Uniform Resource Identifier) pour l'espace de noms en lecture seule. |
| Set Objet_Node = Objet_DocumentFragment.nextSibling |
| contient le frère suivant de ce noeud dans la liste d'enfants des parents en lecture seule. |
| Chaîne = Objet_DocumentFragment.nodeName |
| contient le nom qualifié de l'élément, l'attribut, la référence d'entité ou une chaîne de caractères fixée pour d'autres types de noeud en lecture seule. |
| Valeur = Objet_DocumentFragment.nodeType |
| spécifie le type de noeud XML DOM qui détermine des valeurs valides et si le noeud peut avoir des noeuds enfants en lecture seule. |
| Valeur = Objet_DocumentFragment.nodeTypedValue |
| contient la valeur de ce noeud exprimée dans son type de donnée défini en lecture et écriture. |
| Chaîne = Objet_DocumentFragment.nodeTypeString |
| retourne le type de noeud dans une forme de chaîne de caractères en lecture seule. |
| Valeur = Objet_DocumentFragment.nodeValue |
| contient le texte associé avec le noeud en lecture et écriture. |
| Set Objet_Document = Objet_DocumentFragment.ownerDocument |
| retourne la racine du document qui contient ce noeud en lecture seule. |
| Set Objet_Node = Objet_DocumentFragment.parentNode |
| contient le noeud parent en lecture seule. |
| True | False = Objet_DocumentFragment.parsed |
| contient la valeur True si le noeud et tous ses descendants ont été analysées et instanciées, ou False si n'importe quels noeuds restent à être analysées en lecture seule. |
| Valeur = Objet_DocumentFragment.prefix |
| retourne le préfixe d'espace de noms en lecture seule. |
| Set Objet_Node = Objet_DocumentFragment.previousSibling |
| contient le frère gauche de ce noeud en lecture seule. |
| True | False = Objet_DocumentFragment.specified |
| indique si le noeud est explicitement spécifié ou dérivé d'une valeur par défaut dans le DTD ou le schéma en lecture seule. |
| Chaîne = Objet_DocumentFragment.text |
| contient le contenu textuel du noeud et de sa sous-arborescence en lecture et écriture. |
| Valeur = Objet_DocumentFragment.xml |
| contient la représentation XML du noeud et de tous ses descendants en lecture seule. |
| Méthode |
|---|
| Description |
| Set Objet_Node = Objet_DocumentFragment.appendChild(Nouvel_Enfant) |
| ajoute un nouvel enfant comme le dernier enfant de ce noeud. |
| Set Objet_Node = Objet_DocumentFragment.cloneNode(Bool_Profondeur) |
| crée un nouveau noeud qui est un double exact de ce noeud. |
| True | False = Objet_DocumentFragment.hasChildNodes() |
| retourne True si le noeud a des enfants. |
| Set Objet_Node = Objet_DocumentFragment.insertBefore(Nouvel_Enfant, Référence) |
| insère un noeud enfant à la gauche du noeud spécifié ou à la fin de la liste. |
| Set Objet_Node = Objet_DocumentFragment.removeChild(Noeud_Enfant) |
| enlève le noeud enfant spécifié de la liste d'enfant et le retourne. |
| Set Objet_Node = Objet_DocumentFragment.replaceChild(Nouvel_Enfant, Ancien_Enfant) |
| remplace l'ancien noeud enfant spécifié par le nouveau noeud enfant fourni dans le jeu d'enfants de ce noeud. |
| Set Objet_NodeList = Objet_DocumentFragment.selectNodes(Expression_Pattern) |
| applique l'opération de mise en correspondance de modèles indiquée au contexte de ce noeud et retourne la liste de noeuds correspondants. |
| Set Objet_Node = Objet_DocumentFragment.selectSingleNode(Chaîne_Requête) |
| applique l'opération de mise en correspondance de modèles indiquée au contexte de ce noeud et retourne la liste de premier noeud correspondant. |
| Chaîne = Objet_DocumentFragment.transformNode(Objet_StyleSheet) |
| traite ce noeud et ses enfants utilisant la feuille de style de tranformation (XSLT) indiquée et retourne la transformation résultante. |
| Objet_DocumentFragment.transformNodeToObject(Feuille_Style, Objet) |
| traite ce noeud et ses enfants utilisant la feuille de style de tranformation (XSLT) indiquée et retourne la transformation résultante dans l'objet fourni. |
<%
Const OpenFileForReading = 1
Dim obj_fso, obj_dom, obj_log, racine
Dim obj_client, obj_document, obj_protocole, obj_code, obj_methode
Dim document_txt, protocole_txt, code_txt, methode_txt
Dim adresse_ip, methode, document, protocole, code, poids
Dim tableau, elt_adresse, i
i = 1
Set obj_fso = Server.CreateObject("Scripting.FileSystemObject")
fichier = Server.MapPath("fichier_log.txt")
Set obj_log = obj_fso.OpenTextFile(fichier, OpenFileForReading)
Set obj_dom = Server.CreateObject("MSXML2.DOMDocument")
Set racine = obj_dom.createElement("statistique")
obj_dom.appendChild racine
Set fragment_client = obj_dom.createDocumentFragment()
Do While Not obj_log.AtEndOfStream
ligne = obj_log.ReadLine
tableau = Split(ligne, " ", -1, 1)
elt_adresse = Split(tableau(3), ",", -1, 1)
adresse_ip = tableau(0)
methode = Right(elt_adresse(0), Len(elt_adresse(0)) - 1)
document = elt_adresse(1)
protocole = Left(elt_adresse(2), Len(elt_adresse(2)) - 1)
code = tableau(4)
poids = tableau(5)
Set obj_client = obj_dom.createElement("client")
obj_client.setAttribute "adresse_ip", adresse_ip
Set obj_document = obj_dom.createElement("document")
Set document_txt = obj_dom.createTextNode(document)
obj_document.setAttribute "poids", poids
Set obj_protocole = obj_dom.createElement("protocole")
Set protocole_txt = obj_dom.createTextNode(protocole)
Set obj_code = obj_dom.createElement("code")
Set code_txt = obj_dom.createTextNode(code)
Set obj_methode = obj_dom.createElement("methode")
Set methode_txt = obj_dom.createTextNode(methode)
obj_document.appendChild document_txt
obj_protocole.appendChild protocole_txt
obj_code.appendChild code_txt
obj_methode.appendChild methode_txt
obj_client.appendChild obj_document
obj_client.insertBefore obj_protocole, obj_client.childNodes.item(1)
obj_client.insertBefore obj_code, obj_client.childNodes.item(2)
obj_client.insertBefore obj_methode, obj_client.childNodes.item(3)
fragment_client.appendChild obj_client
racine.appendChild fragment_client
i = i + 1
Loop
obj_dom.save(Server.MapPath("fichier_log.xml"))
Response.Write "Le fichier de statistique au format XML" _
& " est disponible à l'adresse suivante :<br>" _
& Server.MapPath("fichier_log.xml")
obj_log.close
Set obj_log = Nothing
%> |