L'objet IXMLDOMDocumentType contient les informations associées à la déclaration de type de document.

<!DOCTYPE Elément_Racine ... >

Chaque objet DOMDocument inclut une DTD qui identifie l'objet IXMLDOMDocumentType du document.

L'objet IXMLDOMDocumentType fournit un accès à la liste d'entités et de notations définies pour le document. Les propriétés entities et notations retournent des objets IXMLDOMNamedNodeMap représentant respectivement une collection d'objets IXMLDOMEntity et IXMLDOMNotation.

Set Collection_Entites = Objet_DocumentType.entities

Set Collection_Notations = Objet_DocumentType.notations

Un objet IXMLDOMDocumentType est remarqué dans l'arborescence d'un document XML par un type de noeud précis, en l'occurrence par la valeur numérique 10 ou la chaîne de caractères documenttype retournée respectivement par la propriété nodeType et nodeTypeString.

Valeur_numérique = Objet_DocumentType.nodeType
Chaîne = Objet_DocumentType.nodeTypeString
Les Propriétés
Propriété
Description
Chaîne = Objet_DocumentType.baseName
retourne le nom de base pour le nom qualifié avec l'espace de noms en lecture seule.
Set Objet_NodeList = Objet_DocumentType.childNodes
contient une liste de noeuds contenant les enfants en lecture seule.
Valeur = Objet_DocumentType.dataType
indique le type de données pour ce noeud en lecture et écriture.
Set Objet_Node = Objet_DocumentType.definition
retourne la définition d'un noeud dans le DTD ou le schéma en lecture seule.
Set Objet_NamedNodeMap = Objet_DocumentType.entities
contient une liste d'entités externes et internes qui sont déclarées dans le DTD, en lecture seule.
Set Objet_Node = Objet_DocumentType.firstChild
contient le premier enfant de ce noeud en lecture seule.
Set Objet_Node = Objet_DocumentType.lastChild
contient le dernier noeud enfant en lecture seule.
Chaîne = Objet_DocumentType.name
contient le nom du DTD, en lecture seule.
Chaîne = Objet_DocumentType.namespaceURI
retourne l'URI (Uniform Resource Identifier) pour l'espace de noms en lecture seule.
Set Objet_Node = Objet_DocumentType.nextSibling
contient le frère suivant de ce noeud dans la liste d'enfants des parents en lecture seule.
Chaîne = Objet_DocumentType.nodeName
contient le nom qualifié de l'élément, l'attribut, la référence d'entité ou une chaîne de caractères fixée pour d'autres types de noeud en lecture seule.
Valeur = Objet_DocumentType.nodeType
spécifie le type de noeud XML DOM qui détermine des valeurs valides et si le noeud peut avoir des noeuds enfants en lecture seule.
Objet_Valeur = Objet_DocumentType.nodeTypedValue
contient la valeur de ce noeud exprimée dans son type de donnée défini en lecture et écriture.
Chaîne = Objet_DocumentType.nodeTypeString
retourne le type de noeud dans une forme de chaîne de caractères en lecture seule.
Valeur = Objet_DocumentType.nodeValue
contient le texte associé avec le noeud en lecture et écriture.
Set Objet_NamedNodeMap = Objet_DocumentType.notations
contient une liste d'objets IXMLDOMNotation présents dans le DTD, en lecture seule.
Set Objet_Document = Objet_DocumentType.ownerDocument
retourne la racine du document qui contient ce noeud en lecture seule.
Set Objet_Node = Objet_DocumentType.parentNode
contient le noeud parent en lecture seule.
True | False = Objet_DocumentType.parsed
contient la valeur True si le noeud et tous ses descendants ont été analysées et instanciées, ou False si n'importe quels noeuds restent à être analysées en lecture seule.
Valeur = Objet_DocumentType.prefix
retourne le préfixe d'espace de noms en lecture seule.
Set Objet_Node = Objet_DocumentType.previousSibling
contient le frère gauche de ce noeud en lecture seule.
True | False = Objet_DocumentType.specified
indique si le noeud est explicitement spécifié ou dérivé d'une valeur par défaut dans le DTD ou le schéma en lecture seule.
Chaîne = Objet_DocumentType.text
contient le contenu textuel du noeud et de sa sous-arborescence en lecture et écriture.
Valeur = Objet_DocumentType.xml
contient la représentation XML du noeud et de tous ses descendants en lecture seule.
Les Méthodes
Méthode
Description
Set Objet_Node = Objet_DocumentType.appendChild(Nouvel_Enfant)
ajoute un nouvel enfant comme le dernier enfant de ce noeud.
Set Objet_Node = Objet_DocumentType.cloneNode(Bool_Profondeur)
crée un nouveau noeud qui est un double exact de ce noeud.
True | False = Objet_DocumentType.hasChildNodes()
retourne True si le noeud a des enfants.
Set Objet_Node =
Objet_DocumentType.insertBefore(Nouvel_Enfant, Référence)
insère un noeud enfant à la gauche du noeud spécifié ou à la fin de la liste.
Set Objet_Node = Objet_DocumentType.removeChild(Noeud_Enfant)
enlève le noeud enfant spécifié de la liste d'enfant et le retourne.
Set Objet_Node =
Objet_DocumentType.replaceChild(Nouvel_Enfant, Ancien_Enfant)
remplace l'ancien noeud enfant spécifié par le nouveau noeud enfant fourni dans le jeu d'enfants de ce noeud.
Set Objet_NodeList =
Objet_DocumentType.selectNodes(Expression_Pattern)
applique l'opération de mise en correspondance de modèles indiquée au contexte de ce noeud et retourne la liste de noeuds correspondants.
Set Objet_Node =
Objet_DocumentType.selectSingleNode(Chaîne_Requête)
applique l'opération de mise en correspondance de modèles indiquée au contexte de ce noeud et retourne la liste de premier noeud correspondant.
Chaîne = Objet_DocumentType.transformNode(Objet_StyleSheet)
traite ce noeud et ses enfants utilisant la feuille de style de tranformation (XSLT) indiquée et retourne la transformation résultante.
Objet_DocumentType.transformNodeToObject(Feuille_Style, Objet)
traite ce noeud et ses enfants utilisant la feuille de style de tranformation (XSLT) indiquée et retourne la transformation résultante dans l'objet fourni.
Exemple [voir] 
<html>
  <body>
    <%
      Const NODE_DOCUMENT_TYPE = 10
      Dim Objet_Document, Noeud, fichier
      Dim affichage, resultat, i
      Dim Collection_Entites, Collection_Notations

      Set Objet_Document = Server.CreateObject("MSXML2.DOMDocument.4.0")

      Objet_Document.async = false
      fichier = Server.MapPath("logitheque.xml")
      Objet_Document.load fichier

      For Each Noeud In Objet_Document.childNodes
        If Noeud.nodeType = NODE_DOCUMENT_TYPE Then
          Set Collection_Entites = Noeud.entities
          Set Collection_Notations = Noeud.notations

          resultat = resultat & "<h2>" & Noeud.nodeName & " ( " _
                     & Noeud.nodeTypeString & " )</h2>" _
                     & "<h3>Nombre total d'entités : " _
                     & Collection_Entites.length & "</h3>" _
                     & "<h3>Nombre total de notations : " _
                     & Collection_Notations.length & "</h3><hr>"

          resultat = resultat & "<table><tr><th>Entités</th>" _
                          & "<th>Notations</th></tr><tr><td valign='top'>"

          For i = 0 To Collection_Entites.length - 1
            resultat = resultat & "<b style='color: blue; font-weight: bold'>" _
                     & Collection_Entites.item(i).nodeName & "</b> (" _
                     & Collection_Entites.item(i).nodeTypeString _
                     & ") = <b " & "style='font-size: 14pt'>" _
                     & Collection_Entites.item(i).text & "</b><br>"
          Next

          resultat = resultat & "</td><td valign='top'>"

          For i = 0 To Collection_Notations.length - 1
            resultat = resultat & "<b style='color: blue; font-weight: bold'>" _
                     & Collection_Notations.item(i).nodeName _
                     & "</b> (" & Collection_Notations.item(i).nodeTypeString & ") " _
                     & "<b style='color:red'>[ SystemID = '" _
                     & Collection_Notations.item(i).systemID & "' - PublicID = '" _
                     & Collection_Notations.item(i).publicID & "' ]</b><br>"
          Next

          resultat = resultat & "</td></tr></table>"

        End If
      Next

      Response.Write resultat
    %>
  </body>
</html>