L'Altruiste : Le langage VBScript - L'instruction <i>Class</i>

L'instruction Class permet de déclarer le nom d'une classe, et également de définir les variables, les propriétés et les méthodes afférentes à cette classe.

Class Nom
  ' Instructions...
End Class

Nom spécifie l'appellation de la classe.

Instructions représentent n'importe quelles instructions VBScript permettant de définir des variable, propriétés et méthodes appropriées à la création de classes.

Exemple : [voir]

<html>
  <body>
    <%
      Class livre
        Private titre_livre
        Private prix_livre

        Private Sub Class_Initialize
          Response.Write "<p><i>La classe est initialisée</i></p>"
        End Sub

        Private Sub Class_Terminate
          Response.Write "<p><i>La classe est détruite</i></p>"
        End Sub

        Public Property Let titre(valeur)
          titre_livre = valeur
        End Property

        Public Property Get titre
          titre = titre_livre
        End Property

        Public Property Let prix(montant)
          prix_livre = FormatNumber(montant,2,-1)
        End Property

        Public Property Get prix
          prix = prix_livre
        End Property

        Public Property Get convFrancsEuro
          convFrancsEuro = FormatNumber(prix_livre * (1 / 6.55957),2)
        End Property

        Public Sub reduction(taux)
          if taux > 5 then
            taux = 5
          End If
          prix_livre = FormatNumber(prix_livre - (prix_livre * taux / 100),2,-1)
        End Sub
      End Class

      Dim objet

      Set objet = New livre
      objet.titre = "ASP 3.0 : Le guide du développeur"
      objet.prix = 298.00

      Response.Write "<h2>Le livre " & objet.titre  & "</h2>" _
                           & "<h4>Prix : " & objet.prix & " Francs "
      Response.Write "<em style='font-size:10pt'>(" _ 
                           & objet.convFrancsEuro & " Euro)</em></h4>"
      objet.reduction 5
      Response.Write "<h4 style='color:green'>Si vous êtes abonnés, " 
                           & "vous bénéficiez d'une réduction de maximum 5%.</h4>"
      Response.Write "<h4>Prix réduit : " & objet.prix & " Francs</h4>"
      Set objet = Nothing
    %>
  </body>
</html>