L'instruction Property permet de déclarer, un nom, des arguments et le code formant une propriété, dans une déclaration de classe créée par la commande Class.

[Public | Private] Property Get | Let | Set Nom_Propriété [(Arguments)]
  ' Instructions...
  [Exit Property]
  ' Instructions...
End Property

La définition dans un espace de nom d'une propriété peut s'effectuer soit dans le domaine privée, c'est-à-dire valable essentiellement au sein de la classe dans laquelle elle a été déclarée, soit dans le domaine privée (par défaut), soit dans tout un programme VBScript.

Nom_Propriété représente le nom de la propriété concernée et (Arguments), sa propre liste d'arguments séparées par des espaces blancs.

Exit Property est une instruction optionnelle permettant de sortir immédiatement de la propriété en cours.

Les instructions Let, Get et Set

L'instruction Let affecte la valeur de la propriété.

Public Property Let propriete(valeur)
  valeur_propriete = valeur
End Property

L'instruction Property Let peut contenir en son sein des commandes d'affectations Set permettant d'affecter une référence à une propriété.

L'instruction Get obtient la valeur de la propriété.

Public Property Get propriete
  propriete = valeur_propriete
End Property

L'instruction Set définit la référence à un objet.

Public Property Set propriete([arguments,] reference)
  ...
End Property
Exemple : [voir] 
<html>
  <body>
    <%
      Class livre
        Private titre_livre
        Private prix_livre

        Private Sub Class_Initialize
          Response.Write "<p><i>La classe est initialisée</i></p>"
        End Sub

        Private Sub Class_Terminate
          Response.Write "<p><i>La classe est détruite</i></p>"
        End Sub

        Public Property Let titre(valeur)
          titre_livre = valeur
        End Property

        Public Property Get titre
          titre = titre_livre
        End Property

        Public Property Let prix(montant)
          prix_livre = FormatNumber(montant,2,-1)
        End Property

        Public Property Get prix
          prix = prix_livre
        End Property

        Public Property Get convFrancsEuro
          convFrancsEuro = FormatNumber(prix_livre * (1 / 6.55957),2)
        End Property

        Public Sub reduction(taux)
          if taux > 5 then
            taux = 5
          End If
          prix_livre = FormatNumber(prix_livre - (prix_livre * taux / 100),2,-1)
        End Sub
      End Class

      Dim objet

      Set objet = New livre
      objet.titre = "ASP 3.0 : Le guide du développeur"
      objet.prix = 298.00

      Response.Write "<h2>Le livre " & objet.titre  & "</h2>" _
                           & "<h4>Prix : " & objet.prix & " Francs "
      Response.Write "<em style='font-size:10pt'>(" _ 
                           & objet.convFrancsEuro & " Euro)</em></h4>"
      objet.reduction 5
      Response.Write "<h4 style='color:green'>Si vous êtes abonnés, " 
                           & "vous bénéficiez d'une réduction de maximum 5%.</h4>"
      Response.Write "<h4>Prix réduit : " & objet.prix & " Francs</h4>"
      Set objet = Nothing
    %>
  </body>
</html>
Instruction Description
Property Get Déclare le nom, les arguments et le code formant une procédure Property qui obtient (renvoie) la valeur d'une propriété.
Property Let Déclare le nom, les arguments et le code formant une procédure Property qui affecte la valeur d'une propriété.
Property Set Déclare le nom, les arguments et le code formant une procédure Property qui définit la référence à un objet.