L'instruction Select Case est une structure de choix, proposant de multiples possibilités de branchement conditionnel.

Select Case Variable
  Case Condition
    ' Instructions...
   Case Seconde_Condition
     ' Instructions...
   Case Troisième_Condition
     ' Instructions...
   ...
   Case Else
     ' Instructions...
End Select

En fait, cette instruction signifie : exécuter un bloc d'instructions selon le cas (case) correspondant à la valeur de la variable test.

Variable est en fait une expression de chaîne de caractères ou numérique contenant une valeur a tester par rapport à chacun des cas spécifiés.

La dernière commande Case Else détermine le dernier cas possible si aucune des conditions précédentes ne convenait.

Exemple : [voir] 
<html>
  <head>
    <script language="VBScript" type="text/vbscript"> 
    <!--
      Sub validation
        Dim doc
        Dim valeur
        Set doc = Document.forms("formulaire")
        valeur = doc.age.Value
        If IsNumeric(valeur) Then
          Select Case valeur
            Case 1
              MsgBox "Vous êtes encore un bébé !"
            Case 7
              MsgBox "Vous avez atteint l'âge de raison."
            Case 10
              MsgBox "La première dixaine !"
            Case 15
              MsgBox "Les années lycées commencent !"
            Case 18
              MsgBox "Vous avez la majorité, enfin !"
            Case 25
              MsgBox "Vous investissez le marché du travail."
            Case 30
              MsgBox "Vous vous êtes fixés dans votre carrière professionnelle."
            Case 55
              MsgBox "Vous préparez activement la retraite."
            Case 65
              MsgBox "Vous êtes à la retraite."
            Case 75
              MsgBox "Vous profitez pleinement de votre retraite."
            Case 100
              MsgBox "Vous êtes centenaire. Bravo pour cette longévité !"
            Case Else
              MsgBox "Votre âge : " & valeur & " ans"
          End Select
        Else
          MsgBox "Veuillez entrer une valeur numérique seule !" & chr(13) & "Merci !"
        End If
      End Sub
    -->
    </script>
  </head>
  <body>
    <p>Veuillez saisir votre âge :</p>
    <form id="formulaire" 
               action="selectcase.asp"
               onsubmit="validation(); return false;"
               language="jscript">
      <input name="age" type="text" size="4">
      <input name="Valider" type="submit" value="Valider">
    </form>
  </body>
</html>