L'instruction With permet d'appliquer des instructions à un objet spécifié.

With Objet
  ' Instructions...
End With

Objet est le nom d'un objet quelconque ou une fonction qui retourne un objet.

Une telle instruction agit sur un unique objet sans qu'il soit nécessaire de le rappeler pour chaque commandes qu'elle contient. Elle peut être utilisée pour modifier les propriétés d'un objet par exemple.

Exemple : [voir] 
<html>
  <body>
    <%
      Class livre
        Private titre_livre
        Private prix_livre
        Private commentaire_livre

        Private Sub Class_Initialize
        End Sub

        Private Sub Class_Terminate
        End Sub

        Public Property Let titre(valeur)
          titre_livre = valeur
        End Property

        Public Property Get titre
          titre = titre_livre
        End Property

        Public Property Let commentaire(texte)
          commentaire_livre = texte
        End Property

        Public Property Get commentaire
          commentaire = commentaire_livre
        End Property

        Public Property Let prix(montant)
          prix_livre = FormatNumber(montant,2,-1)
        End Property

        Public Property Get prix
          prix = prix_livre
        End Property

        Public Property Get convFrancsEuro
          convFrancsEuro = FormatNumber(prix_livre * (1 / 6.55957),2)
        End Property

        Public Sub reduction(taux)
          if taux > 5 then
            taux = 5
          End If
          prix_livre = FormatNumber(prix_livre - (prix_livre * taux / 100),2,-1)
        End Sub
      End Class

      Dim objet

      Set objet = New livre

      With objet
        .titre = "ASP 3.0 : Le guide du développeur"
        .commentaire = "Ce livre complet vous permet d'apprendre " _
                   & "la technologie ASP en découvrant tour à tour " _
                   & "le HTML, le VBScript, les composants ASP, l'intégration " _
                   & "des bases de données, l'utilisation des classes, de " _
                   & "Internet Information Server, de Microsoft Transaction " _
                   & "Server, ainsi que des exemples d'applications."
        .prix = 298.00

        Response.Write "<h2>Le livre " & .titre  & "</h2>" _
                    & "<h4>Commentaire :</h4><p>" & .commentaire & "</p>"
        Response.Write "<h4>Prix : " & .prix & " Francs "
        Response.Write "<em style='font-size:10pt'>(" _ 
                          & .convFrancsEuro & " Euro)</em></h4>"
        .reduction 5
        Response.Write "<h4 style='color:green'>Si vous êtes abonnés, " _
                        & "vous bénéficiez d'une réduction de maximum 5%.</h4>"
        Response.Write "<h4>Prix réduit : " & .prix & " Francs</h4>"
      End With

      Set objet = Nothing
    %>
  </body>
</html>